Простой TCP сервер на Haskell с Network.Socket

Написание сервера при наличии богатых библиотек для работы с сетью - вещь нетрудная. Но новичкам чаще всего не хватает хорошего комментированного примера.

В данной статье мы рассмотрим написание простейшего TCP-сервера на  Haskell.

Наш сервер будет получать сообщение, переворачивать его и посылать обратно. Для этого нам необходимы модули Network.Socket и Network.Socket.ByteString.

Конечно можно обойтись функционалом модуля Network.Socket, но использование ByteString придаст скорости нашему серверу.
Также есть модуль для работы с ленивыми ByteString. Он так и называется Network.Socket.ByteString.Lazy.

Сам модуль Network.Socket.ByteString содержит лишь четыре функции send, sendTo, recv, recvFrom. Остальные мы импортируем из Network.Socket.
import Network.Socket hiding (send, recv)

import Network.Socket.ByteString
import Control.Concurrent (forkIO)
import qualified Data.ByteString.Char8 as B8
import System.Environment (getArgs)

Вы заметили, что из модуля Network.Socket мы импортировали все, кроме send и recv? Send и recv имеются в модуле для работы с ByteString. Именно эти две функции мы и будем использовать. Поэтому импорт Network.Socket.ByteString можно сделать таким:

import Network.Socket.ByteString (send, recv)

Для работы с ByteString мы импортировали Data.ByteString.Char8 (данный модуль можно было импортировать без префикса). Для многопоточности мы будем использовать forkIO.

Теперь беремся за функционал!

server :: PortNumber -> IO ()
server port = withSocketsDo $ do
                sock <- socket AF_INET Stream defaultProtocol
                bindSocket sock (SockAddrInet port 0)
-- Слушаем сокет. 
-- Максимальное кол-во клиентов для подключения - 5.
                listen sock 5
-- Запускаем наш Socket Handler.
                sockHandler sock                 
                sClose sock

sockHandler :: Socket -> IO ()
sockHandler sock = do
-- Принимаем входящее подключение.
  (sockh, _) <- accept sock
-- В отдельном потоке получаем сообщения от клиента.
  forkIO $ putStrLn "Client connected!" >> receiveMessage sockh
  sockHandler sock

receiveMessage :: Socket -> IO ()
receiveMessage sockh = do
  msg <- recv sockh 10 -- Получаем только 10 байт.
  B8.putStrLn msg -- Выводим их.
-- Если сообщение было пусто или оно равно "q" (quit)
  if msg == B8.pack "q" || B8.null msg
-- Закрываем соединение с клиентом.
  then sClose sockh >> putStrLn "Client disconnected"
  else receiveMessage sockh -- Или получаем следующее сообщение.

Собственно это все. Чтобы запустить наш сервер на 3000-м порту, необходимо в ghci(hugs) вызвать функцию:

server 3000

Либо через функцию main:

main = do
[port'] <- getArgs
  server (fromIntegral $ read port')

Тогда можно будет скомпилировать все в бинарник:

ghc -o tcpserver TCPServer.hs

И запустить:

tcpserver 3000

На самом деле это чуть более "низкоуровневый" вариант, нежели если использовать функции модуля Network.  Пример вы можете посмотреть здесь. Полученный код можно посмотреть на github:gist.